The Statue Got Me High: Annotated Source

I've annotated source text for several of my text adventures, to distribute to a certain tier of my Patreon supporters. One such Patreoneer told me that I should make some of the older annotations available publicly. Now, I'm not one to allow my Patreon supporters to boss me around—I'm an artist, and very passionate about my artistic integrity—but in this case the guy making the suggestion was Simon Carless, and him I do allow to boss me around.

So here is the annotated source code text of Simon's favorite game, "The Statue Got Me High." If you haven't played this game, you should definitely give it a look before you wade into the source. It shouldn't take more than an hour to play through.

"The Statue Got Me High," written as part of a tribute to the They Might Be Giants album Apollo 18 in 2012, is I think the third game I ever released. The nuts and bolts of the implementation do not meet the high standards that I hold myself to as an Inform 7 developer in 2017. Some of the code is embarrassing. But if you're interested in using Inform 7 to create text adventures, this should be a useful example to you—just, please, promise me you won't learn too much.

"The Statue Got Me High"

by Ryan Veeder (with apologies to Johns L & F)

Volume 0 - Introduction to the Annotated Source Code Text

[% Comments in brackets and italics, beginning with a % for some reason, are my 2015 annotations—or my 2017 annotations, new to this general release of the source text. Comments in brackets but not in italics are my original comments to the code, but you won't see many of those. The division headings are all original to the source, except for the one above, obviously. Oddly, it looks like I never declared a "Volume 1." Well, it's too late to do anything about it now.

The most basic explanation of this game's existence is explicated under "carry out abouting" below. I felt really lucky that I got "dibs" on my favorite Apollo 18 track (one of my favorite TMBG tracks, maybe one of my all-time favorite songs) and I really wanted to do it justice. I remember discussing the concept with my brother: That I should pay simultaneous homage to the Commendatore scene in Don Giovanni was a given, but I think it was his idea for the player character to fill the Leporello role. (Sean and I are big fans of the Commendatore scene only because our dad played that part of Amadeus for us over and over again when we were kids. We are not opera buffs.)

I also remember Sean worrying that if I released a game were centered around a dinner, following on the heels of Taco Fiction and You've got a Stew Going, I ran the risk of becoming "the food guy," the Weird Al of IF. I knew the risks, and I made this game. History will be my judge.]

The release number is 2.

[% I am sorry to say I have very little idea of what was changed or fixed for this version. I remember the wine bottles were very buggy, and so was John's behavior in the final scene. There are still bugs in this version, but rather than fix them for a version 3, I'll try to point them out to you as we go.]

The story headline is "A disaster simulator".

The story description is "As his personal assistant, your duty tonight is to make sure John's party is successful. This will not happen. Written for the Apollo 18+20 tribute album project."

[% This story description is uncharacteristically wordy, and on IFDB I've pared it down quite a bit. My philosophy on "blurbs" is informed quite a bit by how much Emily Short disliked the original blurb for Taco Fiction and how much Jenni Polodna loved the sentence "Taco Fiction is a game about crime."]

Use no scoring.

[% The latest versions of Inform 7 assume that a game will not use scoring—also, the latest versions of Inform 7 use the term "story" rather than "game." Back in 2012, though, you had to explicitly turn this option off.]

Include Basic Screen Effects by Emily Short.

[% Emily Short's Basic Screen Effects extension is what I use to make the player Press Any Key To Continue, a technique I rely on to manage pacing at a couple different points in this game.]

Release along with cover art and an interpreter.

Abouting is an action out of world. Understand "help" and "about" and "walkthrough" and "hint" as abouting.

Carry out abouting: say "[italic type]This game was written for the Apollo 18+20 project, organized by Professor Doctor Doctor Kevin Jackson-Mead, DDS. It's based on a song by They Might Be Giants.[paragraph break]My brother Sean and my friend Zach helped me out a lot with the concept and stuff, so props to those guys. This version fixes many bugs that were found by ClubFloyd, so props to those guys as well.[paragraph break]If you find yourself stuck in the game, just make sure you talk to everyone and explore everything thoroughly. Things [if the statue is onice]aren't as bad[otherwise]are exactly as bad[end if] as they seem[roman type]."

[% The "onice" or "onfire" status of the statue object is used as a global variable, indicating that things either have taken a sharp left turn or they haven't yet. When things get crazy, basically every bit of text in the game has to change to reflect that, so we'll see an "if... otherwise... end if" structure used over and over again.]

When play begins:
  now the right hand status line is "";
  say "John was already on his phone by the time you glanced over your shoulder. He had forgotten the whole joke; he wouldn't have noticed if you just turned around and walked back. Which you really wanted to do, for some reason.

It felt like a pretty stupid thing to be afraid of.

You got up the nerve to walk past the last few headstones, but you kept your head down. You didn't even want to look at the feet. You just kept your eyes on the pedestal, on the exact spot where you finally set down the envelope, and then you turned around.

John was still talking to his phone, oblivious. You could feel it, though, like a finger lightly scraping up the back of your neck.

And then jabbing into your spine so you had to turn back around and look up at its face. And you thought (right away you told yourself the idea was ridiculous) that it nodded.

[fixed letter spacing] [variable letter spacing][italic type][bracket]press any key[close bracket][roman type][paragraph break]";
  wait for any key;

[% I find myself unsatisfied with this introductory text. The problem is that the premise is too convoluted to support such an air of mystery. "Inviting a statue of a dead guy to a party" is a complicated concept, and has to be expressed somewhat explicitly in order for what follows to be intelligible.]

Chapter - Boring

[% Nowadays I typically make "Boring" its own volume. These are mostly verbs that don't affect the game state, but which, if I didn't assign new responses, wouldn't match the tone of the rest of the prose.]

The description of the player is "[if the statue is onfire]Suddenly you find the thought of looking at yourself disgusting.[otherwise]You look extremely presentable in your 'B' tuxedo: classy, but not too flashy; easy to ignore. Tuxedo B is the most appropriate for these intimate get-togethers with John's close friends. ([quotation mark]Intimate' is the word John uses for mixed groups; the parties to which only women are invited he calls 'friendly,' and they require a different tuxedo.)[end if]"

Instead of taking some scenery: Say "[if the location is Kitchen or the location is Tunnel or the location is Wine Cellar]You won't be needing that. You assume as much, anyway[otherwise if the statue is onfire]You can't save it. You have to escape[otherwise]It would be untoward to try rearranging [the noun] while guests are over[end if]."

Instead of attacking something: say "[if the statue is onfire]Violence begets violence begets violence et cetera et cetera et cetera[otherwise]No matter how frustrating things become, you must try to keep your head[end if]."

Instead of attacking someone: say "[if the statue is onfire]Violence begets violence begets violence et cetera et cetera et cetera[otherwise]No matter how frustrating things become, you must try to keep your head[end if]."

Instead of kissing someone: say "[if the statue is onfire]Too late for that[otherwise]Keep your mind on the party[end if]."

Check eating:
  if the noun is edible:
    say "That's for the guests." instead;
  otherwise:
    say "Surely you are not so desperate." instead.

[% I just checked, and NOTHING IN THE GAME IS EDIBLE. So much for being the Weird Al of IF!]

Instead of waking up: say "[if the statue is onfire]What makes you think this isn't real?[otherwise]You are very much awake.[end if]"

Instead of sleeping, say "[if the statue is onfire]You can sleep when you're dead[unicode 8212]which might be right now, actually. Hmm[otherwise]You'll have plenty of time to sleep after the party[end if]."

Instead of entering something:
  say "You are not the type to sit down on the job."

[% This makes more sense than it seems to, because Inform 7's default world model has a single "entering" action that covers going through doors, climbing inside of containers, and sitting down on things. When I added this rule I probably hadn't thought very much about exactly what enterable containers or sit-on-able supporters would be in the game, but I knew enough about the player character to decide that I should probably block this action generally—There's always the option to override a general rule like this with more specific rules.

UNFORTUNATELY I didn't think about this quite hard enough, so "You are not the type to sit down on the job" is also the response to >ENTER DOOR. Whoops!!!]

Chapter 2 - Rooms

Section 1 - Kitchen

Kitchen is a room. "[if the statue is onfire]Where's Chucky? It looks like he left in a hurry.[paragraph break]There seems to be something happening down in the dining room[otherwise]The kitchen, with all its drawers, its cupboards, its sinks and ovens, constitutes Chucky's domain, and he guards it jealously. Usually you use it only as a conduit between the dining room (south) and the tunnel to the cellar (down the stairs).[paragraph break]Of course, working in here is part of your job, so you and Chucky have a deal worked out. The deal is: You do not touch [italic type]anything[roman type][end if]."

The stairs are a backdrop. Understand "stair" as the stairs. The stairs are in Kitchen and Tunnel. The description of the stairs is "Creaky, but not dangerous."

Understand "go down stairs" and "go downstairs" as descending.

Descending is an action applying to nothing. Carry out descending: try going down.

Understand "go upstairs" and "go up stairs" as ascending. Ascending is an action applying to nothing. Carry out ascending: try going up.

Instead of taking the stairs:
  if the location is kitchen:
    try going down instead;
  otherwise if the location is tunnel:
    try going up instead.

The kitchen paraphenalia is scenery in the kitchen. Understand "cooking" or "sink" or "sinks" or "drawer" or "drawers" or "cupboard" or "cupboards" or "oven" or "ovens" or "knife" or "spoon" or "fork" or "counter" as the kitchen paraphenalia. The description of the kitchen paraphenalia is "[if the statue is onfire]No, Chucky might be back any minute[otherwise]If you just stand around looking, Chucky will start getting surly[end if]." Instead of doing something other than examining with the kitchen paraphenalia, say "You better not. Chucky would go ballistic."

Chucky is a man in Kitchen. Understand "cook" as Chucky. The initial appearance of Chucky is "[if Chucky carries the stack of place cards]Right now is an exception, apparently.[paragraph break]'John wants you to take care of these,' he squawks, thrusting a stack of cards toward you[otherwise]Chucky [one of]busies himself with some arcane cooking implements[or]just stares, with his one glass eye[or]looks like he wants to hit you[or]takes a quick pull from a bottle of vanilla extract[as decreasingly likely outcomes][end if]."

[% Chucky is an homage to the song "Cyclops Rock," whence his name, his one glass eye, his tombstone smile, and his antisocial tendencies. I believe the president he served under must be Nixon.]

The description of Chucky is "Chucky's teeth look like a cemetery built on some old marshland, his glass eye is not the same color as his real eye, and he smells like a butchery, but he is a phenomenal cook. Supposedly he used to be a chef in the White House.[paragraph break]You'd like to find out more about that, but Chucky isn't the kind of guy who likes to talk. To you."

The tombstone smile is part of Chucky. Understand "teeth" or "tooth" as the tombstone smile. The description of the tombstone smile is "You would think if he really worked for the President, he would be able to afford an orthodontist."

The glass eye is part of Chucky. The description of the glass eye is "His real eye is blue-white, but the glass one is dark green. You don't really like looking straight at it, but you guess doing that would be kind of rude anyway.[paragraph break]Chucky has said, for the record, that he lost the original 'in a fight.' When you told this to John, he said 'Yeah, a fight with a fishing pole!' But he might have been joking."

Instead of asking Chucky about something, say "Chucky isn't big on conversation, even with his friends (you assume)."

Instead of telling Chucky about something, say "Chucky isn't big on conversation, even with his friends (you assume)."

Understand "talk to [Chucky]" as a mistake ("Chucky isn't big on conversation, even with his friends (you assume).").

Chucky carries a stack of place cards. Understand "card" or "stack of cards" or "name cards" as the stack of place cards. The description of the stack of place cards is "The papers are place cards, which are to be set out at the dinner table so everyone knows where to sit. The forms of the names are inconsistent: The men are 'John,' 'Miles,' 'Ivan,' and 'Garry,' but the women are 'Miss Idie' and 'Miss O.'[paragraph break]But that's not your problem. Your job is figuring out where to put these."

[% Forcing the player to get the place cards requires a bit of work. Looking back I wonder why I didn't say "Chucky shoves the cards into your hands" and start the game with the cards in your inventory. I guess I thought it was important to let the player screw around for the first turn instead.]

Check examining the stack of place cards:
  If Chucky carries the stack of place cards:
    say "As you lean in for a closer look, Chucky draws back, repulsed by your intrusion of his personal space.[paragraph break]'Just take [']em, will ya?' he growls. He shoves the stack into your hands and then turns to his cooking.";
    now the player carries the stack of place cards;
    continue the action;

Check taking the stack of place cards:
  if chucky is carrying the stack of place cards:
    now the player is carrying the stack of place cards;
    say "Once the cards are in your hands, Chucky spins around and returns to his cooking." instead.

Check going in Kitchen:
  if Chucky carries the stack of place cards:
    say "'Where do you think you're goin[']?' Chucky barks. 'These cards ain't my job.'" instead.

Instead of going nowhere in Kitchen, say "The stairs go down to the cellar, and south from here is the dining room, and those are the only directions available to you."

Section 2 - Dining Room

Dining is a room. "[if the statue is onfire]Everything is on fire. The floor is burning and the walls are burning and the table looks like a big bonfire; all the settings are twinkling in the light of the flames. The room is rapidly filling with smoke[otherwise]The sun is going down outside the western window, and the huge table, set for six, is aflame in the orange glow. An old portrait hangs on one wall, watching the proceedings with creepy indifference.[paragraph break]The kitchen is back north, the den is east from here, and a narrow door leads south to the foyer[end if]."

The printed name of Dining is "Dining Room". Dining is south of Kitchen.

The huge table is a scenery supporter in dining. The description of the huge table is "[if the statue is onfire]The table has been flipped over and set aflame. The high-backed chairs have been thrown on top like logs. The conflagration is too bright to look at directly[otherwise]At other parties this table has comfortably seated more, but currently there are six high-backed chairs and six table settings: Two each on the north and south sides, one on the west end, and one at the east. This last one, on account of its facing the west wall, has the sunset shining straight at it[end if]."

Some high-backed chairs are scenery in dining. Understand "chair" as the high-backed chairs. The description of the high-backed chairs is "[if the statue is onfire]There are only four chairs burning here. Where are the other two? You doubt they were rescued[otherwise]Depending on the style of dinner to be served, John will request one of the various sets of chairs that he owns to be placed at the table. How he decides which chairs should go with which meals is a mystery[end if]."

Some settings are scenery in dining. The printed name of the settings is "table settings". Understand "table settings" or "setting" or "fork" or "knife" or "spoon" or "salad fork" or "glass" or "plate" or "chopstick" as the settings. The description of the settings is "[if the statue is onfire]Beyond your help, now[otherwise]You look over the settings again, and reposition a [one of]fork[or]spoon[or]salad fork[or]knife[or]glass[or]plate[or]chopstick[at random] ever so slightly.[paragraph break]There. Now it's perfect[end if]."

The portrait is scenery in dining. Understand "John" or "ancestor" or "Don Giovanni" or "Don Juan" or "painting" or "frame" as the portrait. The description of the portrait is "[if the statue is onfire]The man in the portrait reaches out to you for help, but there is nothing you can do[otherwise]The frame on the north wall is too big to ignore, and the eyes of the portrait seem to follow you around.[paragraph break]This is supposed to be John's ancestor, an Old World nobleman, also named John. John has offered numerous anecdotes about the subject of the painting, many of them outlandish and contradictory, and you would be inclined to believe that really has no idea who this man is, if the family resemblence weren't so unnervingly clear[end if]."

[% A sufficiently nerdy player will guess that the ancestor is Don Juan, and we can confirm this hypothesis by understanding "Don Juan" as the portrait. Its creepy eyes also reference TMBG's "No Answer."]

The western window is scenery in dining. Understand "sunset" or "sun" or "setting sun" as the western window. Instead of searching the western window, try examining the noun. The description of the western window is "[if the statue is onfire]Where the window was, there is only a wall of undulating flame[otherwise]The setting sun turns this whole room orange; it's so bright you can't even turn toward it without squinting[unicode 8212]and yet, it is only a middle-sized star[end if]."

[% And here we reference "Why Does The Sun Shine?"!]

Instead of going nowhere in dining, say "[if the statue is onfire]The door to the foyer is blocked. The only way out is east[otherwise]Your available exits are: north to the kitchen, east to the den, and south to the foyer[end if]."

Section 3 - Foyer

Foyer is a room. "[if the statue is onfire]You've almost escaped. The front door is to the south[otherwise]The entrance to the house is somewhat cramped, apparently to allow more room in the parlor to the east. Some steep stairs lead up to the second floor (off-limits, tonight), through a narrow door to the north is the dining room, and the front door leads south and out of the house[end if]."

The narrow door is a door and scenery. The narrow door is north of Foyer and south of Dining. The narrow door is open. The description of the narrow door is "[if open]The narrow door is open, and through it you can see[otherwise]The narrow door is closed, but on the other side of it is[end if] [if the location is foyer]the dining room[otherwise]the foyer[end if]."

Check opening the narrow door:
  if the statue is onfire:
    say "The door is engulfed in flames, impossible to pass." instead.

The front door is a door and scenery. The front door is closed. The front door is north of Lawn and south of Foyer. The description of the front door is "[if the statue is onfire]The door isn't on fire, yet; outside is the lawn, and safety[otherwise]An orange glow burns on the other side of this heavy door[end if]."

Check opening the front door:
  if the statue is onice:
    say "Your duties for the night are inside the house." instead;

After opening the front door:
  say "As you open the door, cool night air rushes in from outside."

The steep stairs is scenery in Foyer. The description of the steep stairs is "[if the statue is onfire]The fire has climbed the stairs and already reached the second floor[otherwise]Vacuuming the carpet on these stairs is one of your favorite jobs, but for some reason you really hate dusting the banister[end if]."

The carpet is part of the steep stairs. The description of the carpet is "[if the statue is onfire]The burning fibers stand at attention, ready to tell you all about how horrible their day has been[otherwise]The freshly-vacuumed fibers stand at attention, ready to receive people's feet[end if]."

Instead of touching the carpet, say "[if the statue is onfire]Your hand passes through the flames like a cannonball through a waterfall, like a meteor through the mesosphere[otherwise]So deep, so soft. You caress the carpet for a bit, and then you rub away the impression left by your hand[end if]."

[% Some neat prose awaits those who bother to take time out to inspect the carpet at the very end of the game!]

The banister is part of the steep stairs. The description of the banister is "[if the statue is onfire]The banister turns away from you in shame[otherwise]You regard the banister with disdain. In just a few days it will be dusty again[end if]."

The broken wall clock is in Foyer. It is fixed in place. The initial appearance of the broken wall clock is "[if the statue is onfire]The wall clock is on the floor, shattered[otherwise]A wall clock hangs silently over you[end if]." The description of the wall clock is "[if the statue is onfire]The exposed gears are sitting around guiltily, waiting for a chance to slink away[otherwise]It's broken; its hands have been stuck at 1:56 for as long as you can remember. John will not permit you to have it fixed[end if]."

[% The clock is stuck at "Four of Two," one of TMBG's kids' songs that started out as a much creepier demo.]

The elephant foot umbrella stand is in Foyer. The umbrella stand is an open unopenable container. The initial appearance of the umbrella stand is "[if the statue is onfire]The elephant foot umbrella stand is here[otherwise]At the bottom of the stairs sits an elephant foot umbrella stand[end if]." The description of the umbrella stand is "[if the statue is onfire]It must have walked here by itself; it's too heavy to be carried[otherwise]John is extremely proud of this extremely illegal conversation piece. He jokes with his lady guests that the rest of the elephant is alive and well: 'He's up in my bedroom,' he says, and then he offers to take her upstairs to see.[paragraph break]This works disturbingly well[end if]."

[% I don't think the umbrella stand is a reference to a TMBG song. I may be misremembering, but I think it was included to reinforce how awful John is.]

Instead of taking the umbrella stand, say "It's too heavy to be lugged around."

Instead of going up in foyer, say "[if the statue is onfire]You'll choke on the smoke even faster if you head up there[otherwise]You don't have to worry about the upstairs for tonight, provided this party doesn't go in an unexpected direction[end if]."

Check going south in foyer:
  if the front door is closed:
    try opening the front door;
    if the front door is open:
      continue the action;

Instead of going nowhere in foyer, say "[if the statue is onfire]The only way out is south[otherwise]Your available exits are north to the dining room, east to the parlor, and south, to the front yard[end if]."

Section 4 - Parlor

Parlor is a room. "[if the statue is onfire]The couch and chair are being rapidly consumed by flames; the rug is almost completely gone.[paragraph break]You can hear people yelling in the foyer to the west[otherwise]This is your favorite room in the house. The décor is classy enough for guests to understand that they should avoid making a mess out of everything.[paragraph break]This is due in large part to the magnificent oriental rug, covering most of the floor, and the delicate sabicu coffee table. Both are in an impossibly pristine condition, capable of inspiring respect from the most boorish of John's associates[end if]." Parlor is east of Foyer.

The beige couch is scenery in Parlor. "[if the statue is onfire]The fire spreads, and ashen black creeps across the suede like a fungus[otherwise]Suede, spotless[end if]."

The easy chair is scenery in Parlor. "[if the statue is onfire]Seams are ripping open in the heat; the edges quickly catch fire[otherwise]You are not allowed to touch John's favorite chair unless you're cleaning it[end if]."

Instead of touching the easy chair, say "You cannot bring yourself to breach your contract[if John is in parlor]. And anyway John is right there[end if]."

The delicate sabicu coffee table is a scenery supporter in Parlor. The description of the coffee table is "[if the statue is onfire]The fire is licking at its base; soon it will be engulfed in flames[otherwise]It's a lovely, lovely piece, regardless of its origins. The vase of lilies you chose is an ideal complement[end if]." The printed name of the coffee table is "coffee table".

Instead of taking the coffee table: say "It's too heavy[if the statue is onfire] for you to save it[end if]."

After examining the coffee table the first time:
  If John is in the location:
    If Miss O is in the location:
      say "Miss O notices that you're looking at the coffee table instead of her. She turns to John.[paragraph break]'I picked this table up during a job in Egypt, remember? Another poor old man with more junk in his life than he knew what to do with. I saw this thing and I could tell in an instant it'd be better off with you. There were complications, though. I wasn't able to take home as much as I wanted.[paragraph break]John's mind has wandered; he takes a moment to respond. 'What kind of complications?'[paragraph break]'Well, the old man was easy; he slept through the whole thing, right? But I was relying on the assistance of his butler. And at the last minute he decided to stop cooperating. So, yeah.'[paragraph break]She glances at you for an instant. Then she closes her eyes and stretches, arching her back. 'I just grabbed his neck for a while until he passed out.'[paragraph break]You look to John. He's trying to look down her dress."

[% It's not explicit in the prose, but Ondine has killed multiple people.]

The vase of lilies is scenery in Parlor. Understand "lily" or "flower" or "flowers" as the vase of lilies. The description of the vase of lilies is "[if the statue is onfire]Garry is holding the lilies over his breast; the vase has disappeared[otherwise]Coral lilies, picking up the orange from the rug, in a eggshell vase to contrast the deep color of the coffee table. John isn't even conscious of how much he relies on you when it comes to stuff like this[end if]."

The magnificent Persian rug is scenery in Parlor. Understand "carpet" or "fibers" as the Persian rug. The description of the rug is "[if the statue is onfire]You can just barely find enough spots that aren't burning yet to get across[otherwise]You've heard again and again the story of how Miss O acquired this carpet (and then so graciously donated it to John). Her speech replays in your mind every time you have to clean it, and it always makes you feel dirty[end if]."

Instead of going nowhere in parlor, say "[if the statue is onfire]The way out is west[otherwise]The foyer is west of here; the den is to the north[end if]."

Section 5 - Den

Den is a room. "[if the statue is onfire]The fire has already spread through here; it's climbing up the sides of the pool table and the credenza[otherwise]This room is well-loved by many of John's friends: from those he's brought home for the first time (because it is cozy and dimly lit) to frequent visitors (because they know there's booze in the credenza). The dining room is west; the parlor is south[end if]." Den is east of Dining and north of Parlor.

The pool table is scenery in Den. The description of the pool table is "[if the statue is onfire]The pool table is kicking and contorting itself, trying to get away, but it can't support its own weight[otherwise]Your gorge rises when you look at this pool table, and this is why:[paragraph break]John almost never brings the same woman home twice. One exception is Judy, who shows up every couple of months. Every time John has her over, Judy wants to shoot pool. Every time she plays, she manages to spill her drink on the table or rip the felt or [italic type]something,[roman type] and it is your job, every time, to get the table refelted.[paragraph break]You hate Judy[end if]."

[% "Judy is Your Viet Nam" was a fairly new song when this game was written. I had a fairly unsophisticated understanding of the character in the song at the time, and I don't think I did her justice.]

The credenza is a scenery supporter in Den. Instead of opening the credenza, say "[if the statue is onfire]You open the credenza. The inside of it is teeming with ants. You close the credenza[otherwise]You've been instructed to let the guests help themselves to drinks[unicode 8212]and you're not allowed to drink on the job[end if]." The description of the credenza is "[if the statue is onfire]The credenza shivers uncontrollably[otherwise]John says he stocks this credenza with exclusively lower-end liquors as a 'distraction,' but how exactly that's supposed to work is beyond you. Breaking into the cellar and making off with the really expensive stuff wouldn't be that much harder[end if]."

[% "The inside of it is teeming with ants." is a good example of how I wrote the creepy back-half-of-the-game text. I was rushed, but I knew that the mood I wanted would be best conveyed with a minimum of detail.]

Some bar stools are scenery in Den. Understand "stool" or "bar stool" as the bar stools. The description of the bar stools is "[if the statue is onfire]The bar stool glares at you[otherwise]After standing around all evening, even these uncomfortable stools look inviting[end if]."

Some pool cues are scenery in Den. Understand "pool cue" or "cue" as the pool cues. The description of the pool cues is "[if the statue is onfire]The pool cues have fallen on the floor and are twisting around each other like mating snakes. You should look away[otherwise]According to John, those cues are the best. They're from Germany[end if]."

Some pool balls are scenery in Den. Understand "pool ball" or "cue ball" as the pool balls. The description of the pool balls is "[if the statue is onfire]Nobody's better than anybody else. From now on, they're all 5-balls. Good for them[otherwise]The balls['] irregular clacking annoys you to no end[end if]."

[% You probably missed it, but the description of the pool balls while the house is on fire is MY FAVORITE.]

Instead of going nowhere in den, say "[if the statue is onfire]The way to the entrance is through the parlor, to the south[otherwise]The dining room is west of here; the parlor is south[end if]."

Section 6 - Tunnel

A dia is a kind of thing.

[% Eventually we'll see that the category "dia" is meant for dials.]

Tunnel is a room. "Technically this is more like an antechamber for the main cellar, but the room is longer than it is wide, and the ceiling is pretty low. Besides a boarded-up rathole, there's nothing to look at in here but the stairs up and the (infuriating) door in the south." Tunnel is down from Kitchen.

The boarded-up rathole is scenery in tunnel. Understand "rat" or "hole" or "rat hole" or "board" or "boards" as the rathole. The description of the rathole is "Those pests probably could chew through these boards if they really wanted, but they seem to have gotten the message and found someone else to harass."

Instead of pulling the boarded-up rathole, try opening the noun.

Instead of opening the boarded-up rathole, say "You couldn't pull the board out with your bare hands, assuming you wanted to in the first place."

The cellar door is a door. The cellar door is scenery. The cellar door is south of tunnel and north of Wine Cellar. The description of the cellar door is "This thing is ridiculous.[paragraph break]The corny combination lock on this door is supposed to keep intruders out of the cellar, protecting the most expensive wines and liquors. It cost thousands of dollars to commission and install. It is a stupid, gaudy piece of junk.[paragraph break]There are three dials. You just turn a dial, and it slides over to the next setting. Each dial has three settings. There are only twenty-seven combinations. Any thief could go through all of them in just a few minutes.[paragraph break][description of the left dial][paragraph break][description of the center dial][paragraph break][description of the right dial][paragraph break]A simple padlock would be so much more effective. So much simpler."

Instead of touching the cellar door, say "Cold. Cold like a broken promise."

[It is blowing my mind right now how complicated the code for this combination lock is. It's ridiculous, especially for a place where the joke is supposed to be that it's too simple. The worst part is, I don't know whether I could execute it more elegantly today.

The use of the planets' symbols is an homage to the planetary imagery in the video for "The Statue Got Me High," as well as Apollo 18's association with International Space Year.]

The left dial is scenery in tunnel. The left dial is a dia. Understand "mercury" or "venus" or "earth" as the left dial. The left dial can be merc, venu, or eart. The left dial is merc. The description of the left dial is "The left dial is marked with the astronomical symbols for Mercury, Venus, and Earth. It is currently pointing at [if merc]Mercury[otherwise if venu]Venus[otherwise]Earth[end if]."

Instead of turning the left dial:
  if the left dial is merc:
    say "You turn the left dial until it points at the symbol for Venus.";
    now the left dial is venu;
  otherwise if the left dial is venu:
    say "You turn the left dial until it points at the symbol for Earth.";
    now the left dial is eart;
  otherwise if the left dial is eart:
    say "You turn the left dial until it points at the symbol for Mercury.";
    now the left dial is merc.

The center dial is scenery in tunnel. The center dial is a dia. Understand "mars" or "jupiter" or "saturn" or "middle" or "middle dial" as the center dial. The center dial can be marsh, jupi, or satu. The center dial is marsh. The description of the center dial is "The center dial has the symbols for Mars, Jupiter, and Saturn. It is pointing at [if marsh]Mars[otherwise if jupi]Jupiter[otherwise]Saturn[end if]."

Instead of turning the center dial:
  if the center dial is marsh:
    say "You turn the center dial until it points at the symbol for Jupiter.";
    now the center dial is jupi;
  otherwise if the center dial is jupi:
    say "You turn the center dial until it points at the symbol for Saturn.";
    now the center dial is satu;
  otherwise if the center dial is satu:
    say "You turn the center dial until it points at the symbol for Mars.";
    now the center dial is marsh.

The right dial is scenery in tunnel. The right dial is a dia. Understand "uranus" or "neptune" or "pluto" as the right dial. The right dial can be uran, nept, or plut. The right dial is uran. The description of the right dial is "The right dial has settings for Uranus, Neptune, and Pluto. The symbol for Pluto is the stupidest; it's just a combination of the letters P and L. The dial is currently set to [if uran]Uranus[otherwise if nept]Neptune[otherwise]Pluto[end if]." The right dial is either dan or nap. The right dial is dan.

Instead of turning the right dial:
  if the right dial is uran:
    say "You turn the right dial until it points at the symbol for Neptune.";
    if the right dial is dan:
      if the statue is in dining:
        say "[line break]You hear a scream upstairs. Someone must have just been introduced to Peter.";
        now the right dial is nap;
    now the right dial is nept;
  otherwise if the right dial is nept:
    say "You turn the right dial until it points at the idiotic symbol for Pluto.";
    now the right dial is plut;
  otherwise if the right dial is plut:
    say "You turn the right dial until it points at the symbol for Uranus.";
    now the right dial is uran.

Understand "set [something]" as turning.

Planet is a kind of value. The planets are mercury, venus, earth, mars, jupiter, saturn, uranus, neptune, pluto.

Sturning is an action applying to one thing and one planet. Understand "set [something] to [a planet]" and "turn [something] to [a planet]" as sturning.

[% Inform 7 has a default "setting it to" action, but I decided to supplement it with "sturning" for whatever reason. It is very possible that it had to do with me not really knowing how "setting it to" worked at the time.

Instead of sturning: try turning the noun.

Check opening the cellar door:
  If the left dial is venu:
    if the center dial is jupi:
      if the right dial is nept:
        now the cellar door is open;
        say "The door swings open." instead;
      otherwise:
        say "The door does not budge. You must not have the right combination." instead;
    otherwise:
      say "The door does not budge. You must not have the right combination." instead;
  otherwise:
    say "The door does not budge. You must not have the right combination." instead.

Check going up in Tunnel:
  if progression is 7:
    if the player carries a boite:
      continue the action;
    otherwise:
      say "John expects you to return carrying a bottle of wine."

Section 7 - Cellar

Wine Cellar is a room. "John only buys the most expensive wines and spirits he can find. In the eyes of his friends, anyway, that makes him a conoisseur. This room isn't packed to the brim, but what it does contain is worth defending."

[% Ugh there's a typo!]

A bottle of Thunderbird is here. Understand "sickly yellow" or "sickly" or "yellow" as the bottle of Thunderbird. The initial appearance of the bottle of Thunderbird is "A sickly red and yellow bottle lying on its side in the corner would seem to be the exception." The description of the bottle of Thunderbird is "[if handled]You regard the bottle with disgust. You couldn't possibly serve it to the guests. Maybe you could use it to kill a houseplant[otherwise]What is this swill doing here? How did it get past the security system? It probably belongs to Chucky[end if]."

[% Thunderbird is a real terrible wine that inspired a real great TMBG song. It serves no purpose in this game but to let you choose to disappoint John in the end.]

A boite is a kind of thing. The bottle of thunderbird is a boite. The bottle of prevenge is a boite.

[% Naming the kind "bottle" was not an option in this case. (The parser is REALLY WEIRD about plurals of kinds—I won't get into it.) But I know a little French, and here that comes in handy: "boîte" means "small box." I thought it meant "bottle."]

Check taking the bottle of Thunderbird:
  If the player carries the bottle of Prevenge:
    silently try dropping the bottle of Prevenge;
    now the player carries the bottle of Thunderbird;
    say "You cannot gracefully carry two wine bottles at once. You drop the other bottle first, then scoop up the disgusting one." instead;
  Otherwise if the player carries the crowbar:
    silently try dropping the crowbar;
    now the player carries the bottle of Thunderbird;
    say "You drop the crowbar so that you can carry the repellent bottle." instead.

Instead of opening the bottle of Thunderbird, say "You don't have a corkscrew handy, which is just as well. Just the fumes off of this stuff could be hazardous to your health."

[% The above pieces of text exemplify an odd duality in the narrator's voice. "The repellent bottle" is the voice of the player character, an extremely stuffy individual who uses words like "repellent" to demonstrate refinement. "The fumes off of this stuff" is the voice of the author, a much less formal guy who I think is making fun of the player character sometimes for being so serious. This all makes sense to me, obviously, but I bet it reads as plain old "inconsistent tone" to some players.]

Instead of drinking a boite: try opening the noun.

Instead of opening the bottle of Prevenge, say "You don't have a corkscrew handy, but John probably knows where one is."

The crate of Prevenge is a closed openable container in wine cellar. Understand "lid" or "nail" or "nails" or "box" as the crate of prevenge. The printed name of the crate of Prevenge is "crate of Prévenge". The initial appearance of the crate of prevenge is "Nearby is a crate of a particular wine which John apparently thinks is worth saving for a special occasion."

[% "Prevenge" is not an especially great song, says me, but it has a title that can be made to look like the name of a region of France, which works great for our present purposes.]

Instead of examining the crate of Prevenge, say "[if closed]The sides read 'PRÉVENGE,' which name does not inspire as much awe in your as it does in John and his friends.[paragraph break][italic type]Qua[roman type] wine, it's nothing special; most of its appeal is in how difficult it is to obtain. The bottlers have seen fit to add to this element of the experience by bolting down the lid of the crate[otherwise]The crate is open, ready for all the special occasions John will enjoy in the future[end if]."

Numc is a number that varies. Numc is 0.

Check opening the crate of Prevenge:
  if numc is 0:
    say "You give the top of the crate a tug; it is nailed down. You can't open this crate with your bare hands and leave with your fingernails intact." instead;
  otherwise if numc is 4:
    say "It's already open." instead;
  otherwise:
    say "Although not all the nails are still stuck in the lid, you'd still prefer not to risk broken nails or splinters by yanking out the rest with your bare hands." instead.

Understand the command "open" as something new. Opening with is an action applying to two things. Understand "open [something] with [something]" and "pry [something] open with [something]" and "pry [something] with [something]" as opening with. Understand "use [something] with [something]" as opening with (with nouns reversed). Understand "use [something] on [something]" as opening with (with nouns reversed).

Understand "open [something]" and "pry [something]" and "pry [something] open" as opening.

Check inserting something into the crate of prevenge:
  if the noun is the bottle of prevenge:
    continue the action;
  otherwise if the noun is the bottle of thunderbird:
    say "A hilarious practical joke! A hilarious practical joke indeed. You can't wait until it pays off, which will probably be a year from now.";
    continue the action;
  otherwise:
    say "There wouldn't be much point in that."

Instead of taking the crate of prevenge: say "Taking the entire crate upstairs would be too much[unicode 8212]no matter [italic type]who[roman type] is visiting."

The crate of Prevenge contains a bottle of Prevenge. The printed name of the bottle of Prevenge is "bottle of Prévenge". The description of the bottle of Prevenge is "You had the pleasure of experiencing Prévenge at the same tasting where John decided he had to buy several crates. It's nothing special."

Check taking the bottle of Prevenge:
  if the player carries the bottle of Thunderbird:
    silently try dropping the bottle of Thunderbird;
    now the player carries the bottle of Prevenge;
    say "You cannot gracefully carry two wine bottles at once. You drop the other bottle in favor of the Prévenge." instead;
  otherwise if the player carries the crowbar:
    silently try dropping the crowbar;
    now the player carries the bottle of Prevenge;
    say "You drop the crowbar so that you can carry the Prévenge." instead.

A crowbar is here. The initial appearance of the crowbar is "A crowbar leans against the wall." The description of the crowbar is "Crowbars seem such mean tools, and yet there is an elegance to them."

Check taking the crowbar:
  if the player carries the bottle of thunderbird:
    silently try dropping the bottle of thunderbird;
    now the player carries the crowbar;
    say "You happily discard your bottle, so as to carry the crowbar with both hands." instead;
  otherwise if the player carries the bottle of Prevenge:
    silently try dropping the bottle of prevenge;
    now the player carries the crowbar;
    say "You carefully set down the Prévenge, so that you can carry the crowbar with both hands." instead.

After taking the crowbar, say "It's a crowbar, but you take it.[paragraph break]"

[% THIS IS HILARIOUS. In Curses!, whenever you pick up the wrench, the response is "It's a wrench, but you take it." When I first played the game I had no idea that "it's a wrench" was any type of idiomatic phrase, but I understood that some sort of joke was going on. My message about taking the crowbar is a loving homage to that immortal sentence, which made as much sense to me as this one here makes to anybody else in the world.]

Section 8 - Lawn

[% The "lawn" room is declared indirectly by the definition of the front door in the foyer, and since the only thing that happens here is the end-of-game rule, there's no need to say anything about it. Apparently there's a need for an empty section devoted to it however.]

Chapter 2 - People Other Than Chucky

Progression is a number that varies. Progression is 0.

[% Progression is the number of guests whom the PC has interrogated about their seating preferences.]

Check putting the stack of place cards on something:
  if the second noun is the huge table:
    if progression is 0:
      say "You aren't sure yet about where each card should go. If your haphazard seating arrangement were to upset one of the guests, the entire evening might be ruined." instead;
    otherwise if progression is 6:
      say "You pull out one card from the stack to place on the table, but stop. Something doesn't seem right." instead;
    otherwise:
      say "Although a picture of the ideal seating arrangement is forming in your mind, you can't yet bring yourself to put your cards on the table. There must be some guest whom you haven't asked yet about their preferences.";
  otherwise:
    say "The guests cannot be expected to sit around [the second noun]." instead.

Instead of dropping the stack of place cards:
  say "You don't exactly relish carrying the cards around, but you cannot bring yourself to abandon your seat-arranging duties."

[% There's no code for the solution to the place card problem, so I guess we'll talk about it here: It is unsolvable. The guests' demands contradict each other! However, if you added a seat for an additional male guest, it would be possible to make everybody happy.

Both "puzzles" in the game screw with the player in different ways, and I feel like in many cases the player was less entertained than the author was. I played a game recently that had numerous joke-puzzles along these lines, and it ticked me off: The designer seemed to hold the concept of puzzles in contempt, and included them in the game just for the sake of pointing out how stupid it is to include puzzles in games.

Good puzzles are rad, because they're fun. They give you a chance to be clever. The place card puzzle only lets you feel clever if you figure out that it's intentionally unsolvable, which is a heck of a guess to make—most reasonable players are going to assume that they're missing something, or that I made a mistake. The combination lock puzzle lets you feel clever if you put in the work to brute force it, but everyone knows brute forcing a puzzle is cheating. So I don't know.

Both puzzles have qualities to recommend them, and neither was designed out of any ill intention, of disdain for the player or for the concept of puzzles. If you dislike either of them, though, I think I get where you're coming from.]

Talking to is an action applying to one thing. Understand "talk to [something]" as talking to.

[% The mode of conversation with NPCs is always an interesting choice in a text adventure. Inform 7's built-in machinery assumes that you'll ASK or TELL a given character ABOUT a certain topic, which is a lot of fun (you can reward players' creativity and curiosity by including including responses for a lot of different topics) but it can also be a lot of work to include even the minimum reasonable amount of topics.

I have a lot to say about choice-based conversation models but this isn't really the place.

What I did for this game was reduce (almost) all NPC conversation to a single "talking to" action, which is probably the right move for a short game that's focused more on the NPCs' personalities than on the PC's. John, the main NPC, gets some specific responses to ">ASK JOHN ABOUT..." This kind of makes sense, but I don't think I'd include that kind of asymmetry in a game I wrote today.]

Instead of showing something to someone: Try talking to the second noun.

Instead of asking someone about something: Try talking to the noun.

Instead of telling someone about something: Try talking to the noun.

Instead of giving something to someone: Try talking to the second noun.

[% This game was nominated for a Best NPCs XYZZY. You are about to see how little there is, internally, to each of these characters. That jerk Chucky was the most complicated one.]

Section 1 - Garry Horrible

[% Garry is Mister Horrible from "Someone Keeps Moving My Chair." He has little to do with the song (in this game) and instead offers a weird perspective on this game's theme of guilt.]

Garry Horrible is a man in Dining. Understand "Mr Horrible" or "Mister Horrible" as Garry Horrible. The printed name of Garry Horrible is "Garry". The initial appearance of Garry Horrible is "[one of]Somebody jumps as you walk in. It's John's friend Garry, apparently startled by your entrance[or]Garry leans forward with both hands on the table, staring into the grain of the wood[stopping]." The description of Garry Horrible is "Although lacking your boss's level of animal magnetism, Garry Horrible has charm and wit enough to make up for his unfortunate name. Most of the time.[paragraphbreak]Tonight, he looks like a nervous wreck. There are dark circles under his eyes; his breathing is too loud. His is not a demeanour appropriate to a dinner party."

Instead of talking to Garry Horrible the first time:
  say "You open your mouth to speak to Garry at just the moment that he apparently gathers the courage to talk to you.[paragraph break]'Do you see that painting up there?' he rasps, indicating the portrait on the north wall. 'Don't you think there's something messed up with that guy? He looks really judgmental, right? Like he's judging me. Or you.'[paragraph break]You take a moment to formulate a diplomatic answer, but other thoughts distract you. Why, Garry, are you standing in here, away from the rest of the party, if you hate that painting so much? What is going on in your life that makes you worried that a [italic type]painting[roman type] is judging you?[paragraph break]Garry goes on without you. 'I don't like him. I feel like he's looking at me. You know what? When we sit down for dinner, try and make sure I'm sitting somewhere where I don't have to look at him. One of these two seats,' he says. He points with a shaking hand at the two chairs on the north side of the table.[paragraph break]You nod.";
  increase progression by 1.

Instead of talking to Garry Horrible:
  say "[if the statue is onfire]'I did something bad,' he mumurs, without opening his eyes. 'I took something that didn't belong to me.'[paragraph break]He grimaces. 'I stole from my office. I stole a chair.'[paragraph break]You roll your eyes.[paragraph break]'But I don't deserve a chair. Even the electric chair is too good for me. The statue has come to punish me, and I'll wait here for him to do what he will. After he gets done with John.' He takes a deep breath.[paragraph break]'Message repeats. I did something bad. I took something that didn't belong to me.' Oh, for Pete's sake[otherwise]'Remember!' Garry mutters, almost whispering. 'One of these seats facing away from the painting!' Yeah, yeah[end if]."

Section 2 - Captain Miles

[% Captain Miles is "The Cap'm," and he's based partially on a friend of a friend who had a boat.

"Seems to be nursing one of his migraines" reads to me like I was quoting something, but I can't place it.]

Captain Miles is a man in Den. Understand "Cap" or "Capm" or "Capm Miles" or "Cap'm" or "The Cap'm" as Captain Miles. The initial appearance of Captain Miles is "[if the statue is onfire]Captain Miles seems to be nursing one of his migraines[otherwise]Captain Miles is here, lining up a shot at the pool table[end if]." The description of Captain Miles is "It isn't clear to you whether Captain Miles's title was earned in the armed forces, or signifies his command over some sailing vessel, or else is a nickname bestowed by your boss. Looking him over, the second option seems likely, based on his piped blazer and its nautical-looking coat of arms.[paragraph break]John has referred to Miles and Miss Idie as 'a lock,' although apparently no formal proposal has been made. Currently he appears primarily focused on his game of pool."

Captain Miles wears a piped blazer. The coat of arms is part of the piped blazer.

[% But neither gets a description! I guess I may have made a conscious decision not to include additional description of the NPCs' clothes and accessories, but I think it's more likely that I was in a hurry and I forgot.

In a perfect game, >EXAMINE BLAZER would yield an interesting or at least sensical response that either adds some detail to the world of the game ("The Captain's blazer reminds you of when you were a bellhop at Hell Hotel, etc. etc.") or calls off the player's interest so we can move on to something else ("It's a very smart-looking blazer.") As implemented here, the response is "You see nothing special about the piped blazer."—which, to anyone who knows anything about text adventures, reads as "HELLO PLAYER, I DIDN'T WRITE  A DESCRIPTION" in large, Pokey the Penguin-esque letters.

But if you really don't want the player to worry about the blazer, you can "zero-implement" the object by writing 'understand "blazer" as Captain Miles,' which redirects >EXAMINE BLAZER to print the description of Miles and making it impossible to really focus on the blazer itself. This isn't especially subtle but it gets the message across.]

Instead of talking to Captain Miles the first time:
  say "'Oh, there you are,' says Miles as you approach. 'Listen, I don't know if you've decided who's sitting where for dinner. But I've been getting these real bad migraines lately.'[paragraph break]Ivan looks up from the pool table. 'No kidding? I can give you something for that.' He pulls a pad of paper from inside his jacket.[paragraph break]Miles turns away from you and back toward Ivan. 'Well, I don't know for sure if they're migraines. I know that I'm really sensitive to light.'[paragraph break]Ivan is already writing. 'Doesn't matter. How about codeine? You seem to me like a codeine kind of guy.' He looks slantways at Miles for a moment, then goes back to scribbling. 'Yeah. Here you go. You can get this filled wherever.'[paragraph break]He rips off the sheet and pushes it into Miles's hand. 'Thanks,' Miles stutters, before he turns back to you.[paragraph break]'In the meantime I guess, I'm just saying, I'd rather not sit in that chair that's facing the window while the sun's going down.'";
  increase progression by 1.

Instead of talking to Captain Miles:
  say "Miles diverts his attention from the pool table for a moment. 'Yeah, no, I'm not picky. I'd just rather not sit where I'd have to stare into the sun."

[% Below is the first mention of the room called "barracks," which I used to add to every game where I stored entities that I needed to be outside of the game map entirely. This was before I learned how to use the built-in Inform 7 concept of an object being "offstage" and sending things there by "removing them from play." This is what I'm talking about when I say some of this code is embarrassing.]

Before talking to Captain Miles:
  if the statue is onfire:
    now miles is in barracks;
    say "Miles looks at you through his fingers, still rubbing his head. 'Oh, there you are,' he says.[paragraph break]His fingers are skeleton bones instead of fingers. 'I'm supposed to say something, so I'll say it to you. The thing I'm supposed to say is, I'm sorry.'[paragraph break]Now the skin and muscle is gone from his face. 'Not sure what I'm supposed to be sorry about. It's really hot in here, and it's hard to think. Maybe I'm supposed to be sorry about Hope, you know.'[paragraph break]His face comes back for a second so he can squint in frustration. 'That's a complicated thing to be sorry for. But the other stuff I did, I don't want to admit to doing. So I'll go with that.'[paragraph break]He nods his skull a couple times, then his skeleton falls apart and burns up." instead.

Before examining captain miles:
  if the statue is onfire:
    now miles is in barracks;
    say "Miles looks at you through his fingers, still rubbing his head. 'Oh, there you are,' he says.[paragraph break]His fingers are skeleton bones instead of fingers. 'I'm supposed to say something, so I'll say it to you. The thing I'm supposed to say is, I'm sorry.'[paragraph break]Now the skin and muscle is gone from his face. 'Not sure what I'm supposed to be sorry about. It's really hot in here, and it's hard to think. Maybe I'm supposed to be sorry about Hope, you know.'[paragraph break]His face comes back for a second so he can squint in frustration. 'That's a complicated thing to be sorry for. But the other stuff I did, I don't want to admit to doing. So I'll go with that.'[paragraph break]He nods his skull a couple times, then his skeleton falls apart and burns up." instead.

Section 3 - Doctor Ivan Worm

[% Doctor Worm is "Doctor Worm," of course. He also resembles a weird inverse Gregory House, writing frivolous descriptions for painkillers. His attire is House's but also mine.]

Doctor Ivan Worm is a man in Den. The printed name of Doctor Ivan Worm is "Ivan". Understand "Doctor Worm" or "Dr Worm" as Ivan Worm. The initial appearance of Doctor Ivan Worm is "[if the statue is onfire]Ivan is leaning on a bar stool, apparently standing only with great effort[otherwise]Ivan leans on his cue and regards the table with something like suspicion[end if]." The description of Doctor Ivan Worm is "Of all tonight's guests, Ivan Worm is the most disappointingly dressed. Invitations were meant to give the impression that this was a formal dinner, but Ivan apparently thought this meant that he should wear a ratty blazer over his T-shirt and jeans. He clearly has not shaved for a few days, and if the light in here were better, you would probably be able to see that his fingernails want trimming.[paragraph break]You have no idea why John bothered to invite him."[doctor house basically]

Instead of talking to Doctor Ivan Worm the first time:
  say "When Ivan sees you coming, he puts down his cue and takes you aside.[paragraph break]'Hey. So. I figure those cards you're carrying are for deciding the seating arrangement? For dinner? Pretty fancy.' It is apparent from his breath that he has figured out the secret of the credenza.[paragraph break]'The thing is. There's two things. First thing is, that lady friend of John's. I don't want to sit next to her. She creeps me out. Second thing is, please don't put me next to...' He's started whispering, and now he cranes his head around the room.[paragraph break]'You know who I'm talking about. She's a downer. I don't wanna sit next to her either. I don't know what Miles sees in her.' He must mean Miss Idie.[paragraph break]'I mean, I know what he sees in her. Her mother has that publishing company. And both she and her mother have mitochondrial encephalomyopathy. I mean, look at her. She's like a stick. But with the publishing company, and she's gonna die young. So I can see why Miles would want to get in on that. But that's not really an option for me. So.[paragraph break]'Just, don't put me next to either of those women.' And with that, he finally lets go of you.";
  increase progression by 1.

Instead of talking to Doctor Ivan Worm:
  say "When you try to get his attention, Ivan looks at you from across the pool table and shakes his head, mouthing silently two words which, by your best guess, are '[italic type]no chicks[roman type].'"

Before talking to Worm:
  if the statue is onfire:
    now Worm is in barracks;
    say "The doctor wobbles, then topples; he manages to save himself by falling backward on the pool table.[paragraph break]'I am having an epiphany. Right now I am realizing that I am basically a drug dealer,' he says. 'Because I never stop hooking these people up with their pills. I mean addicts. They're not people, they're addicts.'[paragraph break]His spine falls out of his back, and he flops to the floor.[paragraph break]His eyes widen: he has had another epiphany. 'That was a terrible thing to say,' he gurgles. 'I'm sorry.'[paragraph break]He tries to curl up in a fetal position against a leg of the table, but the table rears back in disgust and stomps him out like an insect." instead.

Before examining Worm:
  if the statue is onfire:
    now Worm is in barracks;
    say "The doctor wobbles, then topples; he manages to save himself by falling backward on the pool table.[paragraph break]'I am having an epiphany. Right now I am realizing that I am basically a drug dealer,' he says. 'Because I never stop hooking these people up with their pills. I mean addicts. They're not people, they're addicts.'[paragraph break]His spine falls out of his back, and he flops to the floor.[paragraph break]His eyes widen: he has had another epiphany. 'That was a terrible thing to say,' he gurgles. 'I'm sorry.'[paragraph break]He tries to curl up in a fetal position against a leg of the table, but the table rears back in disgust and stomps him out like an insect." instead.

Section 4 - Hope Idie

[% This one is kind of bonkers. Hope was originally supposed to be "Withered Hope," from The Else, but her name also refers to "Hope That I Get Old Before I Die," and it emerges that she's also "Your Racist Friend." I don't know whether the second reference was intentional and I'm pretty sure the third one was not.]

Miss Idie is a woman in Den. Understand "withered" or "hope" or "withered hope" or "Ms Idie" or "Hope Idie" as Miss Idie. The initial appearance of Miss Idie is "[if the statue is onfire]Miss Idie is sitting on the floor, staring into the blaze of the table[otherwise]Across the room, fidgiting on a bar stool, is Miss Idie[end if]." The description of Miss Idie is "Hope Idie is a disturbingly thin woman, and her scarf hangs on her like a Halloween decoration on a dead tree. Her eyes seem to wobble in their sockets as she looks around.[paragraph break]Hope is one of the very few female guests you have known John to invite without planning for them to stay overnight. This isn't because she's attached to Captain Miles, either. John has demonstrated on numerous occasions that his hobby is more important to him than his friends.[paragraph break]So you can only guess why he hasn't put the moves on Hope yet, although you feel like it might have something to do with how easy it is to discern the shapes of many of her bones."

Miss Idie wears a long white scarf.

Instead of talking to Miss Idie the first time:
  say "Miss Idie looks down at the cards in your hand. 'Oh yes, there's one thing you should know. I am left-handed.'[paragraph break]She raises her left hand, by way of evidence.[paragraph break]'If you lack experience with left-handed people, of whom there are relatively few, you may not know about the problems that arise when a left-handed person sits to the right of a right-handed person at a meal. Their elbows often bump against each other. It can be very uncomfortable. If two left-handed people sit next to each other, of course, there is no problem. However, I am the only left-handed person here this evening. I have made sure to check. So please make sure that you do not place me with anyone sitting to my left. I would prefer to have someone sitting immediately to my right. If I am made to sit neighborless at the end of a table, I feel like a pariah, excluded from the group because of my unique needs.[paragraph break]'John, your employer, claims to be ambidextrous. However, ambidexterity is a myth. I am sure he has only really managed to use his left hand for specific tasks, and only with a great deal of training.'[paragraph break]She pauses momentarily[unicode 8212]not to let you get a word in edgewise, but to furrow her brow. 'I thought it was unusual that he would say that about himself. I find that most frivolous claims to ambidexterity are made by Orientals.'[paragraph break]Well, that certainly took a turn.";
  increase progression by 1.

[% I am left-handed. The first I ever heard of a specific person claiming to be ambidextrous was Shigeru Miyamoto, when I was maybe ten years old. My reaction was to assume he was lying, for some reason. I really did not believe ambidexterity was a thing, I guess.

But I was a child, and children are idiots. Today my understanding of the universe, of humans and their hands, is much more nuanced.]

Instead of talking to Miss Idie:
  say "Miss Idie will only raise her left hand to you. We get it, lady. You're left-handed."

Before talking to Miss Idie:
  if the statue is onfire:
    now miss Idie is in barracks;
    say "Hope looks up at you and begins pulling off one of her legs.[paragraph break]'I've been informed that I should feel some remorse over my opinions on the Asian race,' she says. She throws her leg onto the burning table and begins removing one of her arms.[paragraph break]'If all I have to do is apologize, then I apologize. There.' She tosses the arm into the flames and gets to work pulling off the other arm.[paragraph break]Her expression changes: she glares at you as if in warning. 'I am being compelled to apologize against my will. None of this is sincere; I'm just acting this out to make him happy.' She jerks her head backward, toward the narrow door. 'I don't know how he's doing it. They're crafty that way. But why am I going on like this?'[paragraph break]She throws her other arm and leg onto the fire glumly. 'There's not much I can do about it now.'[paragraph break]She throws the rest of herself onto the fire, and in an instant the heat shrivels her like a plastic bag." instead.

Before examining Miss Idie:
  if the statue is onfire:
    now miss Idie is in barracks;
    say "Hope looks up at you and begins pulling off one of her legs.[paragraph break]'I've been informed that I should feel some remorse over my opinions on the Asian race,' she says. She throws her leg onto the burning table and begins removing one of her arms.[paragraph break]'If all I have to do is apologize, then I apologize. There.' She tosses the arm into the flames and gets to work pulling off the other arm.[paragraph break]Her expression changes: she glares at you as if in warning. 'I am being compelled to apologize against my will. None of this is sincere; I'm just acting this out to make him happy.' She jerks her head backward, toward the narrow door. 'I don't know how he's doing it. They're crafty that way. But why am I going on like this?'[paragraph break]She throws her other arm and leg onto the fire glumly. 'There's not much I can do about it now.'[paragraph break]She throws the rest of herself onto the fire, and in an instant the heat shrivels her like a plastic bag." instead.

[Miss Idie's bizarre and impossible method of self-immolation comes from the Hindu myth of King Shibi.

As I learned it (from my own incredibly lousy translation for Sanskrit class), Indra and Dharma decided to test Shibi's virtue and took on the form of birds. Dharma flew into Shibi's court as a dove and begged the king to protect him from Indra, who had become a hawk. Shibi took pity on the bird (he did not guess his guests' true nature) and acquiesced, but the hawk pointed out that he needed meat to live, and asked Shibi to offer his own flesh in place of the dove's.

The dove sat on one side of a scale, and Shibi cut out a chunk of his body to place on the other side. It was a big chunk, but it weighed less than the dove. Shibi cut off more of himself, one arm, one leg, the other leg, the other arm, but still the scales were unbalanced. Finally Shibi cut up the rest of himself and threw himself onto the scale.

At this point the birds revealed themselves as gods, and commended Shibi for his selflessness, rewarding him by restoring his body to its original non-chopped-up state.

The story, as it appears in the Hitopadesha, ends on an even weirder note. It says that Indra and Dharma "went inside." The end. It does not say inside of what. My professor said that they "disappeared between the interstices of space-time," but I don't know whether he based that analysis on his knowledge of Indian religion or if he had just made up a cool-sounding explanation of what still strikes me as an extremely creepy sentence.]

Section 5 - John

John is a man in Parlor. The initial appearance of John is "John is sitting in his favorite easy chair, smiling absentmindedly." The description of John is "You've worked for John for so long that you can't decide what you think of him. Is his sarcasm grating, or is it charming? Is he really charming, or just handsome? Does he treat women like bite-sized Snickers because he loves them, or because he hates them?[paragraph break]Then when he tilts his head, you realize: He's just confident. He doesn't need to be handsome or charming. It's all confidence."

Instead of talking to John the first time:
  say "John looks up at you and switches to a different, broader smile. 'Hey, everything going smoothly? Oh, you got the place cards. You know it doesn't matter to me, but you should probably go around and see if anyone has any weird preference about how they sit down. It doesn't matter to me, though, like I said.[paragraph break]'But, you know, Ondine here is the guest of honor, right?' (Miss O touches her collarbone: [italic type]Who, me?[roman type]) 'So, I suppose she would like to be seated to the right of the host. She's a classy lady; she notices that kind of thing.'[paragraph break]You nod dutifully.";
  increase progression by 1.

Instead of talking to John:
  say "[if the statue is onfire]John delivers that winning smile one more time. 'Well, friend, it looks like this is it. I had fun though, right? And you helped[otherwise]'Nothing right now, thanks,' John says, keeping his eyes on Miss O. 'Remember, though, about the guest of honor, on the host's right[end if].'"

Section 6 - Ondine

Miss O is a woman in Parlor. Understand "Ondine" or "Ms O" as Miss O. The initial appearance of Miss O is "[if the statue is onfire]Miss O lurches away from everything she approaches, like the wrong end of a magnet[otherwise]Across from him is Miss O, lounging on the couch as if it were a day bed[end if]." The description of Miss O is "[first time]Miss O detects your gaze immediately, and looks you straight in the eye (continuing to chat with John all the while) until you manage to look away.[paragraph break][only]You do not know what this woman's deal is. She seems to be somewhat older and quite a bit wealthier than John, but she treats him like an equal, and everyone else like stupid children. You are an exception to this rule: she treats you like an exceptionally stupid child.[paragraph break]John loves ([quotation mark]loves[quotation mark]) her, and invites her over at every opportunity. Tonight's event is probably unofficially in her honor. Luckily, she's only ever in town a few times each year."[stole a lot of stuff]

[% There's a comment! 'Stole a lot of stuff' indeed.]

Instead of talking to Miss O the first time:
  say "Miss O raises a single finger, and shuts you up before you can start talking.[paragraph break]'Just a moment, John,' she says. 'Your associate needs for me to cut off our conversation for a moment. I assume it's something important.'[paragraph break]She turns to you. 'Is this about the seating arrangement of the meal? I hadn't bothered to give it any thought. Hmm.'[paragraph break]She licks her lips.[paragraph break]'I suppose I don't have any strong preferences. I'd hate for any of my silly whims to contradict those of the other guests. But don't you think John should sit at the head of the table? I suppose that goes without saying. After all, you're our gracious host, aren't you?'[paragraph break]Miss O has directed this last sentence at John, apparently having decided she's wasted enough attention on you. You quietly step backward.";
  increase progression by 1.

Instead of talking to Miss O:
  say "You cannot bring yourself to interrupt Miss O again. You are prevented not by the duties of your vocation, but by how afraid you are of her."

Miss O wears a black pencil dress. The description of the black pencil dress is "[if the statue is onfire]Half of Miss O's dress is trying to escape from her body; the other half is trying to strangle her[otherwise]There is so much to dislike about Miss O, but you cannot deny her sense of style[end if]."

Before talking to Miss O:
  if the statue is onfire:
    now Miss O is in barracks;
    say "Miss O hobbles over to you as fast as she can.[paragraph break]'I'm sorry,' she gasps. 'I'm sorry.' She reaches to touch your face, but her arm suddenly swings wildly.[paragraph break]It is made of wood. You can see the veins of the grain working their way up to her head.[paragraph break]'I think this might be ironic,' she rasps. But now her head is made of wood, and now she's on fire, and now she is a pile of ashes." instead.

Before examining Miss O:
  if the statue is onfire:
    now Miss O is in barracks;
    say "Miss O hobbles over to you as fast as she can.[paragraph break]'I'm sorry,' she gasps. 'I'm sorry.' She reaches to touch your face, but her arm suddenly swings wildly.[paragraph break]It is made of wood. You can see the veins of the grain working their way up to her head.[paragraph break]'I think this might be ironic,' she rasps. But now her head is made of wood, and now she's on fire, and now she is a pile of ashes." instead.

Section 7 - The Statue

[% Again with the empty subdivisions!

This is probably a good place to explain that if the statue is of Peter Ng, then the daughter whom John boned is "Ana Ng"—ever offstage.]

Volume X - The Every Turn Rule

[% After every turn rules gave me so much trouble in Taco Fiction, I gave this every turn rule its own volume, expecting that it might grow into a 2,000-word monstrosity. Turns out not!

This volume actually includes all the story-progression mechanics, after the above chapters (which should be volumes! Get it together, Ryan!) implemented the locations, the scenery, and the characters. I basically never organize code this way. Here's how I normally organize code:

VOLUME 0 - BORING

  BOOK 1 - Very basic declarations; adding extensions, changing default settings

  BOOK 2 - Custom responses to nonessential default verbs like jumping

  BOOK 3 - Addition of custom verbs, often as nonessential as the defaults, like pointing at things or knocking on doors

VOLUME 1 - GAME-SPECIFIC MECHANICS

  BOOKS for each special thing this game needs to do, like tracking the ship sinking in Captain Verdeterre, tracking how much money you have in Taco Fiction

VOLUME 2 - SCENARIO

  BOOK 1 - A book for each region of the map, usually tied to a segment of the game narrative

    PART 1 - A part for each room in the region, with the room's description and connections to other rooms

      CHAPTER 1 - A chapter for each object in the room, including NPCs, with description and initial appearance

        SECTION 1 - Sections for individual mechanics relating to especially complicated objects (like NPCs)

Story-progression mechanics are usually tied to specific objects or places, so I add them to the appropriate section in "physical space" rather than having a separate section that organizes things in narrative order. This only works because I have all the narrative organization done in my head or on paper before I start coding.]

[% Anyway, here comes the statue! Certain of the statue's and John's lines, like "that's a cold handshake," are rough translations of lyrics from Don Giovanni.]

Every turn:
  If the location is dining:
    if progression is 6:
      increase progression by 1;
      say "Suddenly you hear someone pounding on the front door, with the force and frequency of a lumberjack chopping at a tree trunk. Garry almost jumps out of his skin. 'They're coming after me!' he squeaks.[paragraph break]You turn to answer the visitor, but [if the narrow door is open]through the narrow door you see John[otherwise]on the other side of the narrow door you hear John[end if] jumping up to beat you to it. You listen carefully for who it might be, but you can only barely hear John:[paragraph break]'Well, hello! Whoa, that's a cold handshake. I didn't expect you! I mean, I didn't expect you this late. Everyone else is already here. But I should have forseen you'd have trouble with transportation. Whatever. Come on in.'[paragraph break]You hear a crunching sound.";
      wait for any key;
      say "[line break]It walks in through the narrow door, stooping its head, sending splinters flying from the frame. It lifts its head (it looks at you) and almost touches the ceiling. It looks at Garry. Garry falls to his knees.[paragraph break]John grins. 'Let me introduce you. Peter, this is my friend Garry. Garry, this is Peter. You remember Peter? Peter whose daughter I boned?'[paragraph break]Garry whimpers. John laughs.[paragraph break]'Anyway, he died, and this is a statue of him. He got up and walked here! Tell him why you're here, Pete.'[paragraph break]The statue rumbles: [bold type]Because you invited me.[roman type][paragraph break]'Yeah! I invited the statue to dinner! And he showed up!' John raises his hands in the air and smirks triumphantly. He is not nearly as bothered by this situation as he should be.";
      now John is in dining;
      now the statue is in dining;
      now the initial appearance of John is "John looks at you.";
      now the initial appearance of Garry is "Garry looks up at the statue.";
      now the description of John is "There's something unnatural about how pleased he is with everything right now.";
      now the description of Garry is "Garry is still on his knees. His lips are quivering. Or is he trying to say something?";
      johngetsantsy in one turn from now;

[% This is not a well-kept secret, but if you break into the cellar early, you can bring up the wine before John asks for it, and trigger a non-canon (but happier) ending.]

At the time when johngetsantsy:
  say "John's eyes dart around the room.[paragraph break]'Oh, oh. Look, the table is only set for six. And the place cards haven't been set. This is a disaster. This is inexcusable.'[paragraph break]He walks over to you and takes the stack of cards from out of your hands. He turns toward 'Peter' and grins.[paragraph break]'These are pointless,' he announces, and he starts ripping apart the cards. 'People can sit where they want. I'll have Chucky put out a new setting. Yes. But for now...'[paragraph break]He turns to you and pulls a key from out of his pocket. 'There is a case of wine downstairs which I have been saving for just this kind of occasion. You like wine, right, Pete?'[paragraph break]The statue seems to be trying to furrow its brow. [bold type]I am no longer one of...[roman type][paragraph break]";
  if the player carries the bottle of Prevenge:
    say "'Nonsense! You trying to insult my hospitality?' He turns back to you and his eyes go wide.[paragraph break]'What have you got there?' He takes the bottle of Prévenge out of your hands.[paragraph break]The statue leans in to look. [bold type]Is that Prévenge? Isn't that stuff really expensive?[roman type][paragraph break]'Heck yes! Only the fanciest for my honored guest!' John looks around for a corkscrew. Actually, no. Hold on a second.[paragraph break]So, you had the wine already, before John gave you the key? You brute-forced the combination to the cellar door? You're not supposed to do that! You're messing up the plot of the game![paragraph break]Okay, I guess the statue loves the wine and everyone gets tipsy and the evening goes wonderfully. Hooray for you.";
    end the story saying "This ending is NON-CANON";
  otherwise:
    say "'Nonsense! You trying to insult my hospitality?' He turns back and stares at you for a second, wiggling his eyebrows, before pressing the key into your hand.";
    now the stack of place cards is in barracks;
    now the player carries the ornate key.

The ornate key is in barracks. The description of the ornate key is "This 'key' is supposed to 'unlock' the wine cellar. It is useless. The fiddly piece at the end is too big to fit in any keyhole; the flat piece at the other end is engraved with three symbols: A 'female' sign (a circle with a cross sticking out of it), a curvy number 4, and a little devil's trident. They are the astronomical symbols for Venus, Jupiter, and Neptune. In that order. Venus Jupiter Neptune."

[% I hardly ever use scenes! I honestly do not know how the Inform 7 concept of "scenes" really works because I've always gotten by without them. It looks like I used them in a fairly weird way here:]

Problem 1 is a scene. Problem 1 begins when the statue is in dining. Problem 1 ends when the player carries the ornate key.

Instead of going east in dining during Problem 1, say "You are rooted to the spot."

Instead of going north in dining during Problem 1, say "You are rooted to the spot."

Instead of going south in dining during Problem 1, say "You are rooted to the spot."

Instead of putting the stack of place cards on the huge table during Problem 1, say "But you don't have a card for the new guest."

Problem 2 is a scene. Problem 2 begins when Problem 1 ends. Problem 2 ends when numc is 4.

Instead of going east in dining during problem 2:
  say "John stops you. 'The cellar is through here,' he says, pushing you into the kitchen.";
  try going north.

Instead of going south in dining during problem 2:
  say "John stops you. 'The cellar is through here,' he says, pushing you into the kitchen.";
  try going north.

check going south in kitchen during problem 2:
  if the player carries the bottle of thunderbird:
    say "Your conscience would like to remind you that the bottle you are carrying is not the bottle John wants." instead;
  otherwise if the player carries the bottle of prevenge:
    continue the action;
  otherwise:
    say "John probably wants you to come back with a bottle from the cellar." instead.

check going south in kitchen:
  if the statue is onfire:
    if the player carries the bottle of prevenge:
      continue the action;
    otherwise if the player carries the bottle of thunderbird:
      continue the action;
    otherwise:
       say "John probably wants you to come back with a bottle from the cellar." instead.

check going north in dining:
  if the statue is onfire:
    say "Under the circumstances, going deeper into the house is probably a bad idea."

Barracks is a room. The statue is a neuter person in Barracks. The printed name of the statue is "the statue". The initial appearance of the statue is "The statue looks at you." The description of the statue is "It's the statue of Peter Ng, from the cemetery. It is cut from granite; it is larger than life. It has no joints, but it moves; its eyes are smooth, without irises, but it blinks.[paragraph break]Technically, John wasn't the one who invited it to the party. You were."

[% So it's here that the statue is made flesh! So to speak!]

Instead of talking to the statue:
  say "You can't think of anything to say."

The statue can be onice or onfire. The statue is onice.

[% The rule below is kind of dumb, trying to handle every aspect of the transition between the two halves of the game all on its own. It works, but I don't like it.]

Check opening with:
  if the noun is the crate of prevenge:
    if the second noun is the crowbar:
      if the player does not carry the crowbar:
        silently try taking the crowbar;
      if numc is 0:
        say "You stick the end of the crowbar under the lip of the crate and begin redistributing some force.";
        now numc is 1;
        if the statue is in dining:
          say "[line break]You hear a crunching sound. The dining room is right above you; that must be the statue moving around. The back of your neck tingles: it [italic type]did[roman type] nod at you, back in the cemetery. How long has it been alive? Is it alive?";
        say "[line break]Your leveraging efforts are rewarded: The nail in one corner of the lid pops up. Three to go." instead;
      otherwise if numc is 1:
        say "You reposition yourself and stick the crowbar under the lid again.";
        if the statue is in dining:
          say "[line break]From upstairs: a shriek so shrill it could be steel rasping against glass, or a scream, or you don't know what. You should go up and make sure nobody's hurt.[paragraph break]But then you hear laughter. They're fine.";
        now numc is 2;
        say "[line break]A little more force, and the second nail comes out." instead;
      otherwise if numc is 2:
        say "You wedge in the crowbar again to tackle the third nail.";
        if the statue is in dining:
          say "[line break]Now you hear a low scraping, a scraping that can only be someone dragging those heavy dining room chairs over those gorgeous hardwood floors. Your lips twist in rage; you look at the nail and imagine it is Ivan's head.";
        now numc is 3;
        say "[line break]It slides out of the crate with a pop. Just one more." instead;
      otherwise if numc is 3:
        say "The last one should be easy. You slide in the crowbar...";
        if the statue is in dining:
          say "[line break]Suddenly the party upstairs is silent. No. Suddenly? It had been silent for a few seconds before you noticed anything. Or maybe it's not silent. You can hear something rustling. Or is that just people talking?[paragraph break]You strain to listen, but then all you can hear is your own heartbeat.";
        silently try dropping the crowbar;
        now the crate of prevenge is open;
        now the player carries the bottle of prevenge;
        now numc is 4;
        if the statue is in dining:
          now the statue is onfire;
          now chucky is in barracks;
          now the statue is in foyer;
          now john is in foyer;
          now miss o is in den;
          now the elephant foot umbrella stand is in den;
          now miss idie is in dining;
          now the narrow door is closed;
          now garry horrible is in parlor;
          now captain miles is in dining;
          now the fire is in mainmain;
          now the smoke is in mainmain;
          now the empty chair is in foyer;
          now the description of the statue is "He towers over you; he stares straight through your eyes.";
          now the initial appearance of the statue is "The statue is here.";
          now the description of john is "John sits with his spine straight up against the back of the chair. Flames reach up around him, licking at him adoringly.";
          now the initial appearance of john is "John is sitting in one of the high-backed chairs. The one next to him is empty.";
          now the initial appearance of garry horrible is "Garry lies on the coffee table, his eyes closed, his feet hanging off the end awkwardly.";
          now the description of garry horrible is "He's holding your lilies over his chest. He's sweating all over, but there's a smile on his face.";
          say "The last nail slides out, and the whole lid slides away. You drop your crowbar and pull out a bottle." instead;
      otherwise if numc is 4:
        say "It's already open." instead;
    otherwise:
      say "[The second noun] would be of limited utility in this endeavor." instead;
  otherwise if the noun is the rathole:
    if the second noun is the crowbar:
      say "[one of]The board falls away easily, and to your surprise you find a rat sitting on the other side. It looks up at you guiltily.[paragraph break]'Sorry, man,' it (he?) says. 'I heard about what's about to go down, and I just had to check it out for myself. But maybe I oughta... Never mind. Good luck!'[paragraph break]The rat scampers back into the hole, and you put the board back in its place[or]Unnecessary[stopping]." instead;
    otherwise:
      say "[The second noun] would be of limited utility in this endeavor." instead;
  otherwise:
    try opening the noun instead.

[% The rule below very inelegantly repeats a bunch of the above rule to cover the weird edge case of a player who (1) enters the wine cellar before the statue arrives, (2) goes through all the work of opening the crate, but (3) doesn't take a bottle out, and then (4) goes through the rest of the game normally, coming back to finally take the bottle at the "correct" time. There are so many better ways to handle this whole stupid thing...]

Check taking the bottle of prevenge:
  if the statue is in dining:
    now the statue is onfire;
    now chucky is in barracks;
    now the statue is in foyer;
    now john is in foyer;
    now miss o is in den;
    now the elephant foot umbrella stand is in den;
    now miss idie is in dining;
    now the narrow door is closed;
    now garry horrible is in parlor;
    now captain miles is in dining;
    now the fire is in mainmain;
    now the smoke is in mainmain;
    now the empty chair is in foyer;
    now the description of the statue is "He towers over you; he stares straight through your eyes.";
    now the initial appearance of the statue is "The statue is here.";
    now the description of john is "John sits with his spine straight up against the back of the chair. Flames reach up around him, licking at him adoringly.";
    now the initial appearance of john is "John is sitting in one of the high-backed chairs. The one next to him is empty.";
    now the initial appearance of garry horrible is "Garry lies on the coffee table, his eyes closed, his feet hanging off the end awkwardly.";
    now the description of garry horrible is "He's holding your lilies over his chest. He's sweating all over, but there's a smile on his face.";
    continue the action.

[% Above are a few pieces of text that get forcibly changed at the moment of truth, rather than containing if-clauses in themselves. I think I may have started trying to do them all this way before I realized how stupid that would be.]

The fire is a backdrop. The fire is in barracks. The description of the fire is "Flames are spreading, enveloping everything."

The smoke is a backdrop. The smoke is in barracks. The description of the smoke is "Smoke is rapidly filling the room, but for now you seem to be able to breathe."

The empty chair is an enterable scenery supporter in barracks. Understand "chairs" as the empty chair.

The description of the empty chair is "John sits in one chair; the one next to him is empty. Both are made out of wood."

mainmain is a region. den is in mainmain. dining is in mainmain. foyer is in mainmain. parlor is in mainmain.

[% "statuen" is a variable that just handles the turn-to-turn pacing of the final scene. The method explicated in the Inform 7 documentation for making text unfurl on a turn-by-turn basis is to go through the rows of a table. That would probably be a little less messy in some ways, but the way the Inform 7 IDE works, putting big chunks of text in table entries makes them very difficult to work with.]

statuen is a number that varies. statuen is 0.

[% The text of the final scene has to do a lot of work, explicating both the statue's motivations and John's ethics while quoting both Don Giovanni and "The Statue Got Me High."

At the time, I hadn't decided even in my own mind whether the statue was an agent of divine judgment or a personal vendetta. My opinion now is that he's acting on his own, although I'm not sure why he's allowed to act so dramatically and violently from beyond the grave...]

Every turn:
  if the statue is onfire:
    if the location is foyer:
      if statuen is 0:
        now statuen is 1;
        say "The statue rumbles: [bold type]Repent.[roman type][paragraph break]John sighs in exasperation. 'I already told you, man. I'm sorry for murdering you. I mean, killing you. In self-defense. It was a wrong place, wrong time kind of thing.'[paragraph break][bold type]Repent.[roman type] roars the statue, and a wave of heat rolls out of it like a sonic boom.[paragraph break]'No! I said already! Already I told you this! I cannot apologize for screwing your daughter. I have to be true to myself, man.'[paragraph break][bold type]But you must[unicode 8212][roman type] the statue attempts, but John is on a roll.[paragraph break]'And what myself is, is, a lover. Of ladies. You can't take that away from me. And I can't apologize for that. I mean, I can, but I'm not gonna.'[paragraph break]The statue creaks. It turns toward you.[paragraph break]";
        wait for any key;
        say "[bold type]You.[roman type][paragraph break]It points at the chair next to John. [bold type]It is your turn. Sit. Join your master.[roman type][paragraph break]'Oh, hey!' Now John notices you. 'Look, this guy wants us to apologize for all the terrible stuff we did. I don't know if it's a religious thing, or if he's just angsty about being dead, or what. Either way, we're gonna burn to death, so...'[paragraph break][bold type]Sit.[roman type] insists the statue.[paragraph break]";
      otherwise if statuen is 1:
        now statuen is 2;
        say "[bold type]Sit, and repent.[roman type] The statue seems to want to throw you bodily into the chair.[paragraph break]'Come on!' cries John. 'Let's get this over with!'[paragraph break]";
      otherwise if statuen is 2:
        say "The statue and John both regard you expectantly. The fire is spreading.[paragraph break]";
    if the location is in mainmain:
      say "[creepy][paragraph break]";

Before showing something to someone:
  If the noun is a boite:
    if the second noun is John:
      if the statue is onice:
        if the noun is the bottle of prevenge:
          say "John looks up at you and winks. 'Save that for later, all right?'" instead;
        otherwise:
          say "John recoils in disgust. 'Where'd you get that? Put it away. Put it away before the guests see.'" instead;
      otherwise:
     if the noun is the bottle of prevenge:
       say "'You got the wine!' John's face lights up. 'You're a saint. Go ahead and open it, pour a glass for... Oh, actually, let's wait. It looks like we're gonna die in a fire before we get a chance to enjoy it.'" instead;
    otherwise:
      say "'You got the wine!' John's face lights up. Then he gets a closer look at the bottle.[paragraph break]'Thunderbird? You idiot! You worthless idiot! Why would you think the guests want to put this in their bodies? You know what, idiot? You [italic type]deserve[roman type] to burn to death.[paragraph break][bold type]Yeah.[roman type] adds the statue." instead.

[% The following redundant rule could be replaced with a simple "Instead of giving something to someone, try showing the noun to the second noun." That's what I do in most games nowadays—the built-in Inform 7 distinction between "giving" and "showing" doesn't really apply to the interactions I put in my games.]

Before giving something to someone:
  If the noun is a boite:
    if the second noun is John:
      if the statue is onice:
        if the noun is the bottle of prevenge:
          say "John looks up at you and winks. 'Save that for later, all right?'" instead;
        otherwise:
          say "John recoils in disgust. 'Where'd you get that? Put it away. Put it away before the guests see.'" instead;
      otherwise:
       if the noun is the bottle of prevenge:
         say "'You got the wine!' John's face lights up. 'You're a saint. Go ahead and open it, pour a glass for... Oh, actually, let's wait. It looks like we're gonna die in a fire before we get a chance to enjoy it.'" instead;
       otherwise:
         say "'You got the wine!' John's face lights up. Then he gets a closer look at the bottle.[paragraph break]'Thunderbird? You idiot! You worthless idiot! Why would you think the guests want to put this in their bodies? You know what, idiot? You [italic type]deserve[roman type] to burn to death.[paragraph break][bold type]Yeah.[roman type] adds the statue." instead.

Before asking John about "Judy":
  if the statue is onfire:
    say "'Oh man, Judy. Judy would have loved this,' John says, a faraway look in his eyes." instead;
  otherwise:
    say "'Judy's here?!' John stiffens. 'Tell her this is a private event. Tell her this is a wake. Actually, tell her it's my wake, because I'm dead. Yeah. Wait, no, then she'll want to come in and mourn me. You'd better just tell her the truth. Whatever that is.'"

[% Same thing here: I could have written "Instead of telling someone about something, try asking the noun about the topic understood." And these days I usually do. But in 2012, I was not so adept.]

Before telling John about "Judy":
  if the statue is onfire:
    say "'Oh man, Judy. Judy would have loved this,' John says, a faraway look in his eyes." instead;
  otherwise:
    say "'Judy's here?!' John stiffens. 'Tell her this is a private event. Tell her this is a wake. Actually, tell her it's my wake, because I'm dead. Yeah. Wait, no, then she'll want to come in and mourn me. You'd better just tell her the truth. Whatever that is.'"

To say creepy:
  choose a random row in Table 1;
  say "[italic type][creep entry][roman type]";

[% I was eating at the Quizno's in Iowa City's Old Capitol Mall one night when I heard a woman start screaming at her cell phone. She was standing in the open area between businesses, and I imagine that anybody in the building could hear her. It was incredibly uncomfortable, but it was also deeply surreal, because (as I remember) she never said anything specific, or really argued in any way. Everything she yelled was a dismissal or interruption of whatever her unfortunate interlocutor had just said.

I don't think all of the random creepy sentences are direct quotes from this lady. I know that mere text cannot convey how distressing it was to hear her say "You'renot listening" the way she did. And she said it a lot.]

Table 1
creep
"If that's what you really think, then you need a lobotomy."
"No, you listen to me. I'm tired of this."
"You're not listening. You're not listening."
"Don't think for a minute you're getting away with anything."
"I've had enough of this attitude."
"Have you been paying any attention? At all?"
"And if it doesn't matter to you, then it doesn't matter at all?"
"Would you stop that? There are people watching."
"I'm done with this."
"This is serious. Do you think I'm kidding?"
"I do not need this right now."
"What are you trying to tell me? No. Forget it."
"No. I don't care anymore. Do what you want."
"Do you really need me to tell you this?"
"You wanna let me finish?"
"You do not talk to me that way."
"No. We're not finished."

[% I did a lot of thinking about the ending when I did the first annotations in 2015, and I think I have different feelings now. There's a multilayered moral/ethical question here having to do with whether the statue is justified in immolating all these people, whether the statue is justified in including the PC among them, and whether the PC is acting correctly by accepting or declining this fate. I wasn't really equipped to handle such issues in the text adventure format in 2012, and I kind of doubt I'm so equipped today.

But I think the interpretation that's truest to my worldview is that, while John and his friends are obviously terrible, and the PC is probably not an especially good person, the statue of Peter Ng isn't perfect either—torturing people, compelling them to apologize, and destroying them hasn't really solved anything. To sit down and accept the statue's apocalyptic idea of justice is the "wrong choice" that yields the "bad ending," because it's better to take your fate in your own hands, or something. Good grief this is dumb. I really truly wasn't equipped to handle this kind of thing in the text adventure format in 2012.

Well, the ending does work on the emotional/poetic level (I think???), so there's that.]

Instead of entering the empty chair:
  say "You sit down next to John. The statue looks at you. The flames rise.[paragraph break]John leans back and smiles: his body turns into a pile of ashes. Then yours does too; then the chairs, and then the rest of the house. Everything is gone, except the statue.";
  end the story finally saying "Well. Huh."

Every turn:
  if the location is lawn:
    say "You run out across the lawn: you fall on your face in the grass before you reach the street.[paragraph break]But you're safe. It's dark out here, and cold, and the guests and John and the statue are all behind you. You lie in the grass and breathe in huge gulps as the screaming fire engine sirens fill the air.";
    end the story finally saying "You have escaped."